How to make a Gantt chart in Google Sheets

Four ways to make a Gantt chart in Google Sheets

All four read from the same table: one task per row with Task (column A), Start (B), Working days (C) and End (D). Sheets has the same date functions as Excel, so the end date can skip weekends and holidays: =WORKDAY(B2,C2-1,Holidays!A:A), where the Holidays sheet lists your non-working dates. NETWORKDAYS counts working days between two dates, and WORKDAY.INTL handles other weekends. Check your dates are real dates rather than text: Sheets right-aligns dates, so a start date sitting on the left of its cell won’t work in any of the formulas below.

Method 1: Timeline view (some paid Workspace plans)

Google Sheets has a Timeline view that turns rows with dates into cards on a scrolling timeline, which is the closest thing Sheets has to a built-in Gantt chart. It has been limited to certain paid Google Workspace plans (business, enterprise and education editions), and Google changes plan details from time to time. The quick test: select your data, open the Insert menu and look for Timeline. If it isn’t there, your account doesn’t have it.

1. Select your task table, headers included.
2. Choose Timeline from the Insert menu. Sheets adds a new tab for the view.
3. In the settings panel, tell it which column holds the start date, the end date (or duration) and the card title.
4. Optionally, group the cards by a column such as phase or owner, and colour them by another.
5. Zoom between days, weeks, months and longer spans. The view updates when you change the table.

It’s good for spotting overlaps, but it stops short of a Gantt chart. There are no milestone diamonds, and dates are edited in the table rather than by dragging on the timeline. Don’t confuse it with the Timeline chart type in the chart editor, which plots values over time as a line and won’t draw task bars.

Method 2: shade a grid with conditional formatting

This works on every Google account, including free personal ones, and it’s the easiest of the four to keep up to date.

1. Leave a spare column after your table, then put dates across row 1. For weeks, start with the Monday before your first task (=MIN(B2:B)-WEEKDAY(MIN(B2:B),3)) and add 7 in each cell to the right. For days, add 1.
2. Select the grid below the dates, starting at the top-left cell (say F2).
3. Open Format > Conditional formatting, and under Format rules choose “Custom formula is”.
4. For a weekly grid enter =AND(F$1<=$D2, F$1+6>=$B2); for a daily grid, =AND(F$1>=$B2, F$1<=$D2) (add WEEKDAY(F$1,2)<6 inside the AND to leave weekends blank). Write the formula for the top-left cell and Sheets adjusts it across the range.
5. Pick a fill colour. Add further rules above it for other colours, for example tasks where an owner column says “Client”.

This is the same method as the grid in our Excel guide, and our free template is built this way. Upload it to Google Drive and open it with Sheets; the working-day formulas and shading come across. The Excel Gantt chart guide explains how the template works.

Method 3: SPARKLINE bars

SPARKLINE draws a tiny chart inside one cell. Given two numbers and the bar type, it draws them end to end. Make the first part (the gap before the task starts) white and the second part (the task) coloured, and each cell becomes a Gantt bar. Widen one column to about 400 pixels and put this in row 2:

=SPARKLINE({B2-MIN($B$2:$B$20), D2-B2+1},
  {"charttype","bar"; "max",MAX($D$2:$D$20)-MIN($B$2:$B$20)+1;
   "color1","white"; "color2","#1d6a4d"})

The first value is how many days after the project start the task begins; the second is its length in calendar days. max sets the full width of the cell to the whole project, so every row uses the same scale. Fill the formula down and adjust the ranges to fit your table. In locales that write decimals with a comma, Sheets expects semicolons between arguments and backslashes between columns inside the curly braces, so swap those if you get a parse error.

The bars are exact to the day and move the moment a date changes. The trade-off is that there’s no date axis, so readers can see order and overlap but not which week they’re looking at unless you add a date header by hand.

Method 4: a stacked bar chart

The Excel stacked-bar trick works in Sheets too. Add a column for the bar length in calendar days (=D2-B2+1), select the task, start and length columns, and choose Insert > Chart. In the chart editor, set the chart type to stacked bar, then in the series customisation make the start-date series invisible (no fill, or zero opacity). Set the minimum of the date axis to your first start date so the bars aren’t squashed against the right edge; if your task order comes out upside down, reverse it in the axis options or sort the table. Sheets gives you fewer axis controls than Excel, so the date labels can be hard to read.

Does Google have a free Gantt chart?

Not as a separate product. Google doesn’t make a dedicated Gantt chart app, and the Timeline view that comes closest isn’t on free personal accounts. What you do get free is Google Sheets itself, which is enough for the grid, SPARKLINE and stacked bar methods above. Sheets’ own template gallery has also included a basic Gantt template, and the Google Workspace Marketplace lists third-party Gantt add-ons, most of them with paid tiers.

Where a spreadsheet Gantt chart falls short

Sheets does better than Excel on sharing. A view-only link stays current, and File > Version history lets you name versions and restore them. The gaps are elsewhere:

• Every change is a typed date. You can’t drag a bar to move a task or stretch it to change its length.
• Clients see a spreadsheet. Rates, notes and internal columns sit next to the plan unless you build a separate client tab and keep it in sync.
• Weekends and holidays are invisible. WORKDAY gets the dates right, but the grid or chart doesn’t show why a bar is longer than its working days.
• Printing. A wide grid rarely fits one readable page without adjusting column widths and scaling by hand.

If the plan is going to a client, read how to share a Gantt chart with clients for what to show them and how to handle changes.